How to create realistic compositing with ARFoundation in Unity

// (c) 2020 Tongzhou Yu
// Ref. https://forum.unity.com/threads/configuring-ar-foundation-3-0-0-preview-to-work-with-lwrp-or-urp.736583/

Shader "AR Shadows LightWeight RP"
{
	Properties
	{
	}

	SubShader
	{
		Tags
		{
			"RenderType" = "Transparent"
			"RenderPipeline" = "UniversalPipeline"
			"IgnoreProjector" = "True"
		}
		LOD 300

		Pass
		{
			Name "AR Proxy"
			Tags
			{
				"LightMode" = "LightweightForward"
			}

			Blend SrcAlpha OneMinusSrcAlpha
			ZWrite On
			Cull Off

			HLSLPROGRAM
			#pragma prefer_hlslcc gles
			#pragma exclude_renderers d3d11_9x
			#pragma target 2.0

		// -------------------------------------
		// Material Keywords
		#pragma shader_feature _ALPHATEST_ON
		#pragma shader_feature _ALPHAPREMULTIPLY_ON

		// -------------------------------------
		// Lightweight Pipeline keywords
		#pragma multi_compile _ _MAIN_LIGHT_SHADOWS
		#pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE
		#pragma multi_compile _ _ADDITIONAL_LIGHTS_VERTEX _ADDITIONAL_LIGHTS
		#pragma multi_compile _ _ADDITIONAL_LIGHT_SHADOWS
		#pragma multi_compile _ _SHADOWS_SOFT

		// -------------------------------------
		// Unity defined keywords
		#pragma multi_compile _ DIRLIGHTMAP_COMBINED
		#pragma multi_compile _ LIGHTMAP_ON

		//--------------------------------------
		// GPU Instancing
		#pragma multi_compile_instancing

		#pragma vertex HiddenVertex
		#pragma fragment HiddenFragment

		#include "Packages/com.unity.render-pipelines.lightweight/ShaderLibrary/Core.hlsl"
		#include "Packages/com.unity.render-pipelines.lightweight/ShaderLibrary/Lighting.hlsl"

		struct Attributes
		{
			UNITY_VERTEX_INPUT_INSTANCE_ID
			float4 positionOS   : POSITION;
		};

		struct Varyings
		{
			float4 positionCS   : SV_POSITION;
			float4 shadowCoord  : TEXCOORD0;
		};

		Varyings HiddenVertex(Attributes input)
		{
			Varyings output = (Varyings)0;

			UNITY_SETUP_INSTANCE_ID(input);
			UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);

			VertexPositionInputs vertexInput = GetVertexPositionInputs(input.positionOS.xyz);

			output.shadowCoord = GetShadowCoord(vertexInput);
			output.positionCS = vertexInput.positionCS;

			return output;
		}

		half4 HiddenFragment(Varyings input) : SV_Target
		{
			UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);

			half s = MainLightRealtimeShadow(input.shadowCoord);

			return half4(0, 0, 0, 1 - s);
		}
		ENDHLSL
	}

	UsePass "Universal Render Pipeline/Lit/DepthOnly"
	}

		FallBack "Hidden/InternalErrorShader"
}

// (c) 2020 Tongzhou Yu
// Ref. https://forum.unity.com/threads/transparent-shader-receive-shadows.325877/

Shader "AR Shadows BuildIn RP"
{
	Properties
	{
		_Color("Main Color", Color) = (1,1,1,.5)
		_ShadowIntensity("Shadow Intensity", Range(0, 1)) = 0.6
	}


		SubShader
	{

		Tags {"Queue" = "Geometry" }

		Pass
		{
			Tags {"LightMode" = "ForwardBase" }
			Cull Back
			Blend SrcAlpha OneMinusSrcAlpha
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fwdbase

			#include "UnityCG.cginc"
			#include "AutoLight.cginc"
			uniform fixed4  _Color;
			uniform float _ShadowIntensity;

			struct v2f
			{
				float4 pos : SV_POSITION;
				LIGHTING_COORDS(0,1)
			};
			v2f vert(appdata_base v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				TRANSFER_VERTEX_TO_FRAGMENT(o);

				return o;
			}
			fixed4 frag(v2f i) : COLOR
			{
				float attenuation = LIGHT_ATTENUATION(i);
				return fixed4(0,0,0,(1 - attenuation)*_ShadowIntensity) * _Color;
			}
			ENDCG
		}

	}
		Fallback "VertexLit"
}